目次＞５章 第２ステップ（色々な実験）＞スイッチでＬＥＤの点滅パターンを変更＞ソース
スイッチでＬＥＤの点滅パターンを変更（ソース）
更新日２００５．１０．２
以下のソースを取り込んで、アセンブル→ＰＩＣ書き込み→実行して下さい。
; ========================== ここから ==============================
; CLOCK 10MHz
; PORTB 0:LED緑，1:LED赤
;
LIST P=PIC16F84A ; LIST宣言で、使用するPICをPIC16F84Aと定義する
INCLUDE P16F84A.INC ; 設定ファイルp16f84a.incを読み込む
__CONFIG _HS_OSC & _WDT_OFF & _PWRTE_ON & _CP_OFF
cnt04 EQU 0Ch ; 0.4mS待つサブルーチン用カウンタ
cnt20 EQU 0Dh ; 20mS待つサブルーチン用カウンタ
old_sw EQU 0Eh ; 前回ＳＷ状態
mode EQU 0Fh ; ＬＥＤ表示モード
cnt500 EQU 10h ; 500mSをカウント(20mS×25)
ORG 0 ; リセットベクタ(0番地)を指定する。
INIT
; ＜＜ PICの初期化 ＞＞
CLRF PORTB ; PORTBを全てＯＦＦ
BSF STATUS,RP0 ; ファイルレジスタSTATUSのRP0をセット(1)する → バンク1
CLRF TRISB ; ファイルレジスタTRISBをクリア(0) → PORTBは全て出力
MOVLW 01h
MOVWF TRISA ; ファイルレジスタTRISAの０ビット目のみＯＮ → RA0は入力
BCF STATUS,RP0 ; STATUSのRP0をクリア(0) → バンク0
CLRF old_sw ; ０ → 前回ＳＷ状態
MOVLW 01h
MOVWF mode ; １ → ＬＥＤ表示モード
MOVLW D'25'
MOVWF cnt500 ; 25 → 500mSカウンタ(20mS×25)
; ＜＜ メイン処理 ＞＞
MAIN
BTFSC PORTA,0 ; スイッチの状態チェック
GOTO SW_ON ; スイッチがＯＮの時
SW_OFF ; スイッチがＯＦＦの時
CALL T20mS ; 20mS待つ
BTFSS PORTA,0 ; スイッチの状態チェック
CLRF old_sw ; ＯＦＦなら０→前回ＳＷ状態
GOTO DISP ; LED表示処理へ
SW_ON ; スイッチがＯＮの時
CALL T20mS ; 20mS待つ
BTFSS PORTA,0 ; スイッチの状態チェック
GOTO DISP ; ＯＦＦならLED表示処理へ
BTFSC old_sw,0 ; 前回のスイッチ状態はＯＦＦ？
GOTO DISP ; ＯＮならLED表示処理へ
BSF old_sw,0 ; 前回のスイッチ状態がＯＦＦなら１→前回ＳＷ状態
INCF mode,F ; 表示モード＋１
DISP
MOVLW D'1'
SUBWF mode,W
BTFSC STATUS,Z
GOTO DISP1 ; 表示モードが１の時
MOVLW D'2'
SUBWF mode,W
BTFSC STATUS,Z
GOTO DISP2 ; 表示モードが２の時
MOVLW D'3'
SUBWF mode,W
BTFSC STATUS,Z
GOTO DISP3 ; 表示モードが３の時
; 表示モードが１〜３以外の時
MOVLW D'1'
MOVWF mode ; １ → 表示モード
GOTO MAIN
DISP1 ; 表示モードが１の時 緑色ＬＥＤのみ点灯
MOVLW 01h
MOVWF PORTB ; PORTBのRB0のみＯＮにする（緑色ＬＥＤ点灯）
GOTO MAIN
DISP2 ; 表示モードが２の時 緑と赤のＬＥＤを０．５秒毎に交互に点灯
DECFSZ cnt500
GOTO MAIN
; 500mS経過
MOVLW D'25'
MOVWF cnt500 ; 25 → 500mSカウンタ(20mS×25)
BTFSS PORTB,0
GOTO DISP21
MOVLW 02h
MOVWF PORTB ; RB0=0 RB1=1 緑消灯，赤点灯
GOTO MAIN
DISP21
MOVLW 01h
MOVWF PORTB ; RB0=1 RB1=0 緑点灯，赤消灯
GOTO MAIN
DISP3 ; 表示モードが３の時 赤色ＬＥＤのみ点灯
MOVLW 02h
MOVWF PORTB ; PORTBのRB1のみＯＮにする（赤色ＬＥＤ点灯）
GOTO MAIN
; ＜＜ 20mS待つサブルーチン ＞＞
T20mS
MOVLW D'50' ; 50(20mS)
; MOVLW D'100' ; 100(40mS)
MOVWF cnt20 ; （ループ回数として50をセット）
T20LP CALL T04mS ; 0.4mS待つ
DECFSZ cnt20,F ; ループ回数−１して０になったら次の命令をスキップ
GOTO T20LP ;
RETURN ; このサブルーチン呼出し元に戻る
; ＜＜ 0.4mS待つサブルーチン ＞＞
T04mS
MOVLW D'249' ; 249
MOVWF cnt04 ; （ループ回数として249をセット）
T04LP NOP ; 何もせず１サイクル消費
DECFSZ cnt04,F ; ループ回数−１して０になったら次の命令をスキップ
GOTO T04LP
RETURN ; このサブルーチン呼出し元に戻る
END ; プログラムの終了をアセンブラに指示する
; =========================== ここまで ===============================