目次＞５章 第２ステップ（色々な実験）＞ＲＢ０／ＩＮＴ割込みを使う＞ソース
ＲＢ０／ＩＮＴ割込みを使う（ソース）
更新日２００５．１１．２６
以下のソースを取り込んで、アセンブル→ＰＩＣ書き込み→実行して下さい。
; ========================== ここから ==============================
; CLOCK 10MHz
; PORTA 0:高輝度LED，1:LED緑
; PORTB 0:NaPiOn
;
; 人の動きを検出したら明かりを点ける
; ・ＴＭＲ０割込み使用
; ・ＲＢ０／ＩＮＴ割込み使用
;
; SLEEP時、0.19mA
;
LIST P=PIC16F84A ; LIST宣言で、使用するPICをPIC16F84Aと定義する
INCLUDE P16F84A.INC ; 設定ファイルp16f84a.incを読み込む
__CONFIG _HS_OSC & _WDT_OFF & _PWRTE_ON & _CP_OFF
save_st EQU 0Ch ; STATUSのセーブ領域
save_w EQU 0Dh ; W-regのセーブ領域
CNT38 EQU 0Eh ; TMR0割り込みを３８回カウントするカウンタ
CNT10 EQU 0Fh ; 上記３８回をさらに１０回カウントするカウンタ
flag10s EQU 010h ; １０秒経過フラグ
napion EQU 011h ; NaPiOnの出力変化の管理
ORG 0 ; リセットベクタ(0番地)を指定する。
GOTO INIT ; 初期処理に行く
; ＜＜ 割込み処理 ＞＞
ORG 4 ; 割込みベクタ(4番地)を指定する。
MOVWF save_w ; W-regセーブ
SWAPF STATUS,W
MOVWF save_st ; STATUSレジスタセーブ
BTFSC INTCON,T0IF ; ＴＭＲ０割込み？
GOTO T0INT ; Yes
BTFSC INTCON,INTF ; ＲＢ０／ＩＮＴ割込み？
GOTO RB0INT ; Yes
GOTO INTEXIT ; No
T0INT ; ＴＭＲ０割込み処理
BCF INTCON,T0IF ; 割込みフラグクリア
DECFSZ CNT38,F ; CNT38−１が０か？
GOTO INTEXIT ; No
MOVLW d'38'
MOVWF CNT38 ; CNT38に３８をセット
DECFSZ CNT10,F ; CNT10−１が０か？
GOTO INTEXIT ; No
MOVLW d'10'
MOVWF CNT10 ; CNT10に１０をセット
BSF flag10s,0 ; １０秒経過フラグをＯＮ
GOTO INTEXIT
RB0INT ; ＲＢ０／ＩＮＴ割込み処理
BCF INTCON,INTF ; 割込みフラグクリア
BSF PORTA,0 ; RA0 ON
MOVLW d'1'
MOVWF napion ; １→ＮａＰｉＯｎ状態
INTEXIT
SWAPF save_st,W
MOVWF STATUS ; STATUSレジスタロード
SWAPF save_w,F
SWAPF save_w,W ; W-regロード
RETFIE ; 割込み許可にしてリターン
; ここまで割込み処理
INIT
; ＜＜ PICの初期化 ＞＞
BSF STATUS,RP0 ; ↓STATUSのRP0をセット(1)する → バンク1
MOVLW 01h
MOVWF TRISB ; PORTBのRB0のみ入力
CLRF TRISA ; PORTAは全て出力
MOVLW 087h ; OPTIONレジスタの設定
MOVWF OPTION_REG ; ^RBPU:1 ,INTEDG:0 ,T0CS:0 ,PSA:0 ,PS2-PS0:111
BCF STATUS,RP0 ; ↑STATUSのRP0をクリア(0) → バンク0
CLRF PORTA ; PORTAを全てＯＦＦ
CLRF PORTB ; PORTBを全てＯＦＦ
CLRF TMR0 ; TMR0をクリア
MOVLW 0A0h ; INTCONの設定
MOVWF INTCON ; GIE:1 ,T0IE:1(TMR0割り込み許可)
MOVLW d'38'
MOVWF CNT38 ; CNT38に３８をセット
MOVLW d'10'
MOVWF CNT10 ; CNT10に１０をセット
CLRF flag10s
CLRF napion
; ＜＜ メイン処理 ＞＞
BSF PORTA,1 ; 電源ＯＮ後１０秒間ＲＡ１（緑ＬＥＤ）をＯＮにする
WAIT10S ; 電源ＯＮ後、ＮａＰｉＯｎの回路が安定するまで１０秒待つ
BTFSS flag10s,0 ; 10秒経過フラグＯＮ？
GOTO WAIT10S ; No
BCF PORTA,1 ; 電源ＯＮから１０秒経過後、ＲＡ１をＯＦＦにする
BSF INTCON,INTE ; ＲＢ０／ＩＮＴ割込み許可
MAIN
CALL DBG ; ＲＢ０（ＮａＰｉＯｎの出力）の状態をＲＡ１で表示
BTFSS napion,0 ; NaPiOn状態は１？
GOTO NAPI2 ; No
NAPI1
; ＜＜ NaPiOn状態が１の時（RB0/INT割込み発生） ＞＞
CLRF TMR0 ; TMR0クリア
MOVLW d'38'
MOVWF CNT38 ; CNT38に３８をセット
MOVLW d'10'
MOVWF CNT10 ; CNT10に１０をセット
CLRF flag10s ; １０秒経過フラグクリア
MOVLW d'2'
MOVWF napion ; NaPiOn状態を２にする
GOTO MAIN
; ＜＜ NaPiOn状態が１で無い時 ＞＞
NAPI2
BTFSS napion,1 ; NaPiOn状態は２？
GOTO MAIN ; No
BTFSS flag10s,0 ; flag10s(10秒経過フラグ)=１？
GOTO MAIN ; No
BCF PORTA,0 ; RA0をＯＦＦにする
CLRF napion ; NaPiOn状態を０にする
SLEEP ; 省電力モードで待機（RB0/INT割込み待ち）
GOTO MAIN
; ＜＜ ＲＢ０の状態をＲＡ１に反映するサブルーチン ＞＞
DBG
BTFSS PORTB,0 ; NaPiOn = ON?
GOTO DBG010 ; No
BSF PORTA,1
GOTO DBG900
DBG010
BCF PORTA,1
DBG900
RETURN
END
; =========================== ここまで ===============================