---

目次＞５章　第２ステップ（色々な実験）＞（１６）７セグメントＬＥＤを使う（３桁固定数字） ＞ソース２

７セグメントＬＥＤを使う（３桁固定数字）（ソース２）

---

以下のソースを取り込んで、アセンブル→ＰＩＣ書き込み→実行して下さい。

; ========================== ここから ==============================
;   CLOCK   20MHz
;   ７セグメントＬＥＤ×３の制御（カソードコモン）
;   各桁の表示を５ミリ秒毎に切り替える。表示文字は、左から１２３
;	PORTB	７セグメントＬＥＤ（Ａ〜Ｇ，ＤＰ）
;	RA0	2SC1815（７セグ＃３の選択）
;	RA1	2SC1815（７セグ＃２の選択）
;	RA2	2SC1815（７セグ＃１の選択）
;
;
	LIST	P=PIC16F84A	; LIST宣言で使用するPICを16F84Aと定義する。
	INCLUDE	P16F84A.INC	; 設定ファイルp16f84a.incを読み込む。
	__CONFIG	_HS_OSC & _WDT_OFF & _PWRTE_ON & _CP_OFF

	CBLOCK	0Ch
	C02mS	; 0.2mSカウンタ
	C5mS	; 5mSカウンタ
	C1S	; 1Sカウンタ
	ENDC

	ORG	0

	CLRF	PORTA
	BSF	STATUS,RP0	;■ページ１に切替え
	CLRF	TRISB		;RB0-7は出力
	MOVLW	018h
	MOVWF	TRISA		;RA0,1,2は出力
	BCF	STATUS,RP0	;■ページ０に切替え

; ============================================================
main
	CLRF	PORTB		;PORTBを一旦０にする（７セグの全セグメントを消灯）
	MOVLW	04h		;
	MOVWF	PORTA		;RA2のみＯＮ（７セグの３桁目（一番左）を表示）
	MOVLW	06h		;
	MOVWF	PORTB		;７セグに'１'を表示
	CALL	T5mS		;5ミリ秒待つ

	CLRF	PORTB		;PORTBを一旦０にする（７セグの全セグメントを消灯）
	MOVLW	02h		;
	MOVWF	PORTA		;RA1のみＯＮ（７セグの２桁目（真ん中）を表示）
	MOVLW	05Bh		;
	MOVWF	PORTB		;７セグに'２'を表示
	CALL	T5mS		;5ミリ秒待つ

	CLRF	PORTB		;PORTBを一旦０にする（７セグの全セグメントを消灯）
	MOVLW	01h		;
	MOVWF	PORTA		;RA0のみＯＮ（７セグの１桁目（一番右）を表示）
	MOVLW	04Fh		;
	MOVWF	PORTB		;７セグに'３'を表示
	CALL	T5mS		;5ミリ秒待つ

	GOTO	main


; ============================================================
    ; ＜＜　1S待つサブルーチン　＞＞   
T1S
	MOVLW	d'200'
	MOVWF	C1S		; ループ回数として200をセット）
T1SLP	CALL	T5mS		; 5mS待つ
	DECFSZ	C1S,F		; ループ回数−１して０になったら次の命令をスキップ
	GOTO	T1SLP		;
	RETURN			; このサブルーチン呼出し元に戻る


    ; ＜＜　5mS待つサブルーチン　＞＞   
T5mS
	MOVLW	d'25'
	MOVWF	C5mS		; ループ回数として25をセット）
T5mLP	CALL	T02mS		; 0.2mS待つ
	DECFSZ	C5mS,F		; ループ回数−１して０になったら次の命令をスキップ
	GOTO	T5mLP
	RETURN			; このサブルーチン呼出し元に戻る


    ; ＜＜　0.2mS待つサブルーチン　＞＞   
T02mS
	MOVLW	d'249'
	MOVWF	C02mS		; ループ回数として249をセット
T02mLP	NOP			; 何もせず１サイクル消費
	DECFSZ	C02mS,F		; ループ回数−１して０になったら次の命令をスキップ
	GOTO	T02mLP
	RETURN			; このサブルーチン呼出し元に戻る

	END
; =========================== ここまで ===============================

---