---

目次＞５章　第２ステップ（色々な実験）＞　（２０）簡易Ａ／Ｄ変換（積分回路の応用）＞　ソース
簡易Ａ／Ｄ変換
−　積分回路の応用　−

---

以下のソースを取り込んで、アセンブル→ＰＩＣ書き込み→実行して下さい。

; ========================== ここから ==============================
;	PIC16F84A
;	clock:20MHz
;
;
;	ＰＩＣのピン接続
;		RB0	RB0/INT（積分結果入力）
;		RB4	LCD DB4
;		RB5	LCD DB5
;		RB6	LCD DB6
;		RB7	LCD DB7
;
;		RA0	LCD RS	(4:Register Select)
;		RA1	LCD E	(5:Enable Signal)
;		RA3	矩形波出力　→　積分回路
;
;
	LIST	P=PIC16F84A
	INCLUDE	P16F84A.INC
	__CONFIG	_HS_OSC & _WDT_OFF & _PWRTE_ON & _CP_OFF


	CBLOCK	0Ch
	save_w
	save_st
	AD_counter		;AD変換ワーク
	flag			;bit0:INT割込みフラグ
	char			;LCD表示データ
	CNT50uS
	CNT1mS
	CNT5mS
	CNT15mS
	ENDC

f_int	EQU	0		;INT割込みフラグ（ flag[0] ）
RS	EQU	00h		;LCD Register Select
E	EQU	01h		;LCD Enable


	ORG	0
	GOTO	init

; =============== 割り込み処理 (RB0/INT) ====================
	ORG	4		;割込みの入口

	MOVWF	save_w		;W-regセーブ
	SWAPF	STATUS,W
	MOVWF	save_st		;STATUSレジスタセーブ

; ==== INT割込み ====
	BCF	INTCON,INTF
	BSF	flag,f_int	;INT割込みフラグＯＮ

; ==== exit ====
	SWAPF	save_st,W
	MOVWF	STATUS		;STATUSレジスタロード
	SWAPF	save_w,F
	SWAPF	save_w,W	;W-regロード
	RETFIE			;割込み許可リターン

; ============================== 初期処理 =======================
init
	BSF	STATUS,RP0	;■バンク１に切替え
	MOVLW	0F4h		;
	MOVWF	TRISA		;RA0,1,3は出力
	MOVLW	00Fh		;
	MOVWF	TRISB		;RB4-7は出力
	MOVLW	0C1h		;プリスケーラ:4,プルアップなし,RB0/INT立ち上がり
	MOVWF	OPTION_REG
	BCF	STATUS,RP0	;■バンク０に切替え

	CLRF	PORTA		;PORTAをクリア
	CLRF	PORTB		;PORTBをクリア

	CALL	LCD_init	;LCD初期化
	MOVLW	'A'
	CALL	LCD_write
	MOVLW	'D'
	CALL	LCD_write
	MOVLW	'='
	CALL	LCD_write

	BSF	INTCON,GIE

; ============================== メイン =========================
main
	CALL	AD_proc		;簡易A/D変換

	MOVLW	083h		;LCD表示位置を４桁目に
	CALL	LCD_command

	SWAPF	AD_counter,W	;A/D変換の
	ANDLW	00Fh		;上位４ビットを
	CALL	bin2hex		;16進数で
	CALL	LCD_write	;LCDに表示

	MOVF	AD_counter,W	;A/D変換の
	ANDLW	00Fh		;下位４ビットを
	CALL	bin2hex		;16進数で
	CALL	LCD_write	;LCDに表示

	CALL	wait50us	;コンデンサの放電完了待ち(合計200uS)

	GOTO	main

; ========================== Ａ／Ｄ変換処理 =====================
AD_proc
	BCF	flag,f_int	;INT割込みフラグＯＦＦ
	BSF	INTCON,INTE	;RB0/INT割込み許可
	CLRF	AD_counter	;AD変換結果クリア
	BSF	PORTA,3		;AD開始
AD_proc3
	INCF	AD_counter,F
	BTFSS	flag,f_int	;INT割込み（A/D変換終了）？
	GOTO	AD_proc3

	BCF	INTCON,INTE	;RB0/INT割込み禁止
	BCF	PORTA,3

	RETURN


; -----------------------------------------------------
; バイナリ４ビットをＬＣＤ表示用１６進数に変換
bin2hex
	ADDWF	PCL,F

	RETLW	'0'	;0
	RETLW	'1'	;1
	RETLW	'2'	;2
	RETLW	'3'	;3
	RETLW	'4'	;4
	RETLW	'5'	;5
	RETLW	'6'	;6
	RETLW	'7'	;7
	RETLW	'8'	;8
	RETLW	'9'	;9
	RETLW	'A'	;A
	RETLW	'B'	;b
	RETLW	'C'	;C
	RETLW	'D'	;d
	RETLW	'E'	;E
	RETLW	'F'	;F

;================= ＬＣＤ表示をクリアする ===================
LCD_clear
	MOVLW	01h
	CALL	LCD_command
	CALL	wait5ms		;LCDのBFをチェックしないので1.64mS以上待つ
	RETURN

;================= ＬＣＤのカーソル位置を先頭に戻す =========
LCD_home
	MOVLW	080h
	CALL	LCD_command
	RETURN

;================= ＬＣＤのカーソル位置を２行目の先頭に =====
LCD_2line
	MOVLW	0C0h
	CALL	LCD_command
	RETURN

;================= ＬＣＤのディスプレイをＯＮにする =========
LCD_on
	MOVLW	0Ch
	CALL	LCD_command
	RETURN

;================= ＬＣＤのディスプレイとカーソルをＯＮにする ==
LCD_on_cur
	MOVLW	0Eh
	CALL	LCD_command
	RETURN

;================= ＬＣＤのディスプレイをＯＦＦにする =======
LCD_off
	MOVLW	08h
	CALL	LCD_command
	RETURN

;================= ＬＣＤにデータを送る =====================
LCD_write
	MOVWF	char

	BSF	PORTA,RS	;RS=1(Data)

	MOVLW	00Fh		;PORTBの上位４ビットを
	ANDWF	PORTB,F		;　クリア
	MOVF	char,W		;上位
	ANDLW	0F0h		;４ビットを
	IORWF	PORTB,F		;PORTB(4-7)にセット（PORTB(0-3)はそのまま）
	BSF	PORTA,E		;ＬＣＤにデータ書き込み
	NOP
	BCF	PORTA,E

	MOVLW	00Fh		;PORTBの上位４ビットを
	ANDWF	PORTB,F		;　クリア
	SWAPF	char,W		;下位
	ANDLW	0F0h		;４ビットを
	IORWF	PORTB,F		;PORTB(4-7)にセット（PORTB(0-3)はそのまま）
	BSF	PORTA,E		;ＬＣＤにデータ書き込み
	NOP
	BCF	PORTA,E

	CALL	wait50us	;LCDのBFをチェックしないので50uS待つ

	RETURN

;================= ＬＣＤにコマンドを送る ===================
LCD_command
	MOVWF	char

	BCF	PORTA,RS	;RS=0(Command)

	MOVLW	00Fh		;PORTBの上位４ビットを
	ANDWF	PORTB,F		;　クリア
	MOVF	char,W		;上位
	ANDLW	0F0h		;４ビットを
	IORWF	PORTB,F		;PORTB(4-7)にセット（PORTB(0-3)はそのまま）
	BSF	PORTA,E		;ＬＣＤにデータ書き込み
	NOP
	BCF	PORTA,E

	MOVLW	00Fh		;PORTBの上位４ビットを
	ANDWF	PORTB,F		;　クリア
	SWAPF	char,W		;下位
	ANDLW	0F0h		;４ビットを
	IORWF	PORTB,F		;PORTB(4-7)にセット（PORTB(0-3)はそのまま）
	BSF	PORTA,E		;ＬＣＤにデータ書き込み
	NOP
	BCF	PORTA,E

	CALL	wait50us	;LCDのBFをチェックしないので50uS待つ

	RETURN

;================= LCD初期化 ================================
LCD_init
	BCF	PORTA,RS	;RS=0
	BCF	PORTA,E		;E=0

	MOVLW	030h		;上位４ビットに'３'をセット
	MOVWF	PORTB
	BSF	PORTA,E		;ファンクションセット（１回目）
	NOP
	BCF	PORTA,E
	CALL	wait5ms		;5mS待つ

	BSF	PORTA,E		;ファンクションセット（２回目）
	NOP
	BCF	PORTA,E
	CALL	wait5ms		;5mS待つ

	BSF	PORTA,E		;ファンクションセット（３回目）
	NOP
	BCF	PORTA,E
	CALL	wait5ms		;5mS待つ

	MOVLW	020h		;４ビットモード
	MOVWF	PORTB		;に
	BSF	PORTA,E		;設定
	NOP
	BCF	PORTA,E
	CALL	wait1ms		;1mS待つ

	MOVLW	028h		;４ビットモード，２行表示，７ドット
	CALL	LCD_command
	CALL	LCD_off		;ディスプレイＯＦＦ
	CALL	LCD_clear	;ＬＣＤクリア
	MOVLW	06h		;
	CALL	LCD_command	;カーソルモードセット (Increment)
	CALL	LCD_on		;ディスプレイＯＮ，カーソルＯＦＦ

	RETURN


;================= 15mS WAIT ================================
wait15ms
	MOVLW	d'3'
	MOVWF	CNT15mS
wait15ms_loop
	CALL	wait5ms
	DECFSZ	CNT15mS,F
	GOTO	wait15ms_loop
	RETURN

;================= 5mS WAIT =================================
wait5ms
	MOVLW	d'100'
	MOVWF	CNT5mS
wait5ms_loop
	CALL	wait50us
	DECFSZ	CNT5mS,F
	GOTO	wait5ms_loop
	RETURN

;================= 1mS WAIT =================================
wait1ms
	MOVLW	d'20'
	MOVWF	CNT1mS
wait1ms_loop
	CALL	wait50us
	DECFSZ	CNT1mS,F
	GOTO	wait1ms_loop
	RETURN

;================= 50μS WAIT ===============================
wait50us
	; １サイクル（４クロック）：０．２μＳ
	; ５０μＳ＝０．２μＳ×２５０サイクル

	MOVLW	d'82'		;1
	MOVWF	CNT50uS		;1
wait50us_loop
	DECFSZ	CNT50uS,F	;1
	GOTO	wait50us_loop	;2
	RETURN			;2+1

	END
; ========================== ここまで ==============================

---