目次＞８章．機能が豊富なＰＩＣを使う(PIC12F683)＞ＧＰ２／ＩＮＴ割り込みを使う＞ソース
ＧＰ２／ＩＮＴ割り込みを使う（ソース）
（ひとの動きを検出したら明かりを点ける）更新日２００６．１．１５
以下のソースを取り込んで、アセンブル→ＰＩＣ書き込み→実行して下さい。
; ========================== ここから ==============================
;
; PIC12F683
; clock:INTOSCIO 1MHz
; 電源:単三乾電池三本（４．５Ｖ）
;
; 内部クロック１ＭＨｚ
; 全てのピン（６ピン）をデジタルＩＯで使用
; GP0: Ｃｄｓ（入力）
; GP2: ＮａＰｉＯｎ（ＧＰ２／ＩＮＴ）
; GP4: 緑色ＬＥＤ（出力）
; GP5: 高輝度ＬＥＤ（出力）
;
; ＮａＰｉＯｎによりＧＰ２／ＩＮＴ割込みを発生させ、高輝度ＬＥＤを５秒間点灯させる
; Ｃｄｓにより、暗い時のみ動作
; 時間待ちは、ＴＭＲ０割込みを使用
; 人の動きを検出していない時は、ＳＬＥＥＰ状態（省電力待機）にする
;
;
LIST P=12f683
#INCLUDE <p12f683.inc>
__CONFIG _CP_OFF & _CPD_OFF & _WDT_OFF & _BOD_ON & _IESO_OFF& _PWRTE_ON & _INTOSCIO & _MCLRE_OFF
save_st EQU 020h ; STATUSのセーブ領域
save_w EQU 021h ; W-regのセーブ領域
CNT19 EQU 022h ; TMR0割り込みを１９回カウントするカウンタ
napion EQU 023h ; NaPiOn状態フラグ
flag5s EQU 024h ; ５秒経過フラグ
ORG 0
GOTO INIT ; 初期処理に行く
; ＜＜ 割込み処理 ＞＞
ORG 4 ; 割込みベクタ(4番地)を指定する。
MOVWF save_w ; W-regセーブ
SWAPF STATUS,W
MOVWF save_st ; STATUSレジスタセーブ
BTFSC INTCON,T0IF ; ＴＭＲ０割込み？
GOTO T0INT ; Yes
BTFSC INTCON,INTF ; ＧＰ２／ＩＮＴ割込み？
GOTO GP2INT ; Yes
GOTO INTEXIT ; No
T0INT ; ＴＭＲ０割込み処理
BCF INTCON,T0IF ; 割込みフラグクリア
DECFSZ CNT19,F ; CNT19−１が０か？
GOTO INTEXIT ; No
; Yes （５秒経過）
MOVLW d'19'
MOVWF CNT19 ; CNT19に１９をセット
BSF flag5s,0 ; ５秒経過フラグをＯＮ
GOTO INTEXIT
GP2INT ; ＧＰ２／ＩＮＴ割込み処理
BCF INTCON,INTF ; 割込みフラグクリア
MOVLW d'1'
MOVWF napion ; １→ＮａＰｉＯｎ状態
INTEXIT
SWAPF save_st,W
MOVWF STATUS ; STATUSレジスタロード
SWAPF save_w,F
SWAPF save_w,W ; W-regロード
RETFIE ; 割込み許可にしてリターン
; ここまで割込み処理
INIT
; ＜＜ PICの初期化 ＞＞
MOVLW 07h
MOVWF CMCON0 ;GP2-0はデジタルＩＯ
BSF STATUS,RP0 ;■バンク１に切替え
MOVLW 0Fh
MOVWF TRISIO ; GP0-3は入力，GP4-5は出力
MOVLW 087h ; OPTIONレジスタの設定
MOVWF OPTION_REG ; ^RBPU:1 ,INTEDG:0 ,T0CS:0 ,PSA:0 ,PS2-PS0:111
MOVLW 040h ; CLOCK=1MHz
MOVWF OSCCON
CLRF ANSEL ;デジタルＩＯ（ＡＮ機能を使用しない）
BCF STATUS,RP0 ;■バンク０に切替え
CLRF GPIO ; GPIOをクリア
CLRF TMR0 ; TMR0をクリア
MOVLW 0A0h ; INTCONの設定
MOVWF INTCON ; GIE:1 ,T0IE:1(TMR0割り込み許可)
MOVLW d'19'
MOVWF CNT19 ; CNT19に１９をセット
CLRF flag5s
CLRF napion
; ＜＜ メイン処理 ＞＞
BSF GPIO,4 ; 電源ＯＮ後ＮａＰｉＯｎが安定するまで緑色ＬＥＤ点灯
WAIT5S ; 電源ＯＮ後、ＮａＰｉＯｎの回路が安定するまで１０秒待つ
BTFSS flag5s,0 ; 5秒経過フラグＯＮ？
GOTO WAIT5S ; No
BCF GPIO,4 ; 電源ＯＮ後ＮａＰｉＯｎが安定するまで緑色ＬＥＤ点灯
BSF INTCON,INTE ; ＲＢ０／ＩＮＴ割込み許可
MAIN
CALL DISP ; ＮａＰｉＯｎ状態を緑色ＬＥＤで表示
BTFSS napion,0 ; NaPiOn状態は１？
GOTO NAPI2 ; No
NAPI1
; ＜＜ NaPiOn状態が１の時（GP2/INT割込み発生） ＞＞
CLRF TMR0 ; TMR0クリア
MOVLW d'19'
MOVWF CNT19 ; CNT19に１９をセット
CLRF flag5s ; ５秒経過フラグクリア
MOVLW d'2'
MOVWF napion ; NaPiOn状態を２にする
GOTO MAIN
; ＜＜ NaPiOn状態が１で無い時 ＞＞
NAPI2
BTFSS GPIO,0 ; 暗い？
GOTO SLEEPMODE ; No
BTFSS napion,1 ; NaPiOn状態は２？
GOTO MAIN ; No
BSF GPIO,5 ; GP5をＯＮにする
BTFSS flag5s,0 ; flag5s(5秒経過フラグ)=１？
GOTO MAIN ; No
SLEEPMODE
BCF GPIO,4 ; GP4をＯＦＦにする
BCF GPIO,5 ; GP5をＯＦＦにする
CLRF napion ; NaPiOn状態を０にする
SLEEP ; 省電力モードで待機（GP2/INT割込み待ち）
MOVLW D'1'
MOVWF napion ; NaPiOn状態を１にする
GOTO MAIN
DISP
BTFSS GPIO,0 ; 暗い？
GOTO DISP900 ; No
BTFSS GPIO,2 ; NaPiOn = ON?
GOTO DISP010 ; No
BSF GPIO,4
GOTO DISP900
DISP010
BCF GPIO,4
DISP900
RETURN
END
; =========================== ここまで ===============================