---

目次＞６章　第３ステップ（実用品）＞夜、人の動きを検知したら明かりを点ける＞ソース

夜、人の動きを検知したら明かりを点ける（ソース）

---

以下のソースを取り込んで、アセンブル→ＰＩＣ書き込み→実行して下さい。

; ========================== ここから ==============================
;
;	PIC12F683
;	clock:INTOSCIO 8MHz
;	電源:単三乾電池三本（４．５Ｖ）
;
;	内部クロック８ＭＨｚ
;	全てのピン（６ピン）をデジタルＩＯで使用
;	GP0: 未使用
;	GP1: 高輝度ＬＥＤ（出力）
;	GP2: ＮａＰｉＯｎ（ＧＰ２／ＩＮＴ）
;	GP3: Ｃｄｓ
;	GP4: 高輝度ＬＥＤ（出力）
;	GP5: 高輝度ＬＥＤ（出力）
;
;	ＮａＰｉＯｎによりＧＰ２／ＩＮＴ割込みを発生させ、高輝度ＬＥＤを５秒間点灯させる
;	Ｃｄｓにより、暗い時のみ動作
;	時間待ちは、ＴＭＲ０割込みを使用
;	人の動きを検出していない時は、ＳＬＥＥＰ状態（省電力待機）にする
;
;
	LIST	P=12f683
	#INCLUDE <p12f683.inc>

	__CONFIG _CP_OFF & _CPD_OFF & _WDT_OFF & _BOD_OFF & _IESO_OFF& _PWRTE_ON & _INTOSCIO & _MCLRE_OFF

	CBLOCK	020h
	save_st		; STATUSのセーブ領域
	save_w		; W-regのセーブ領域
	CNT19		; TMR0割り込みを１９回カウントするカウンタ
	napion		; NaPiOn状態フラグ
	timer		; タイマー（bit0:5秒）
	C25mS		; 25mSカウンタ（128uS×１９５）
	C5S		; 5Sカウンタ（128uS×１９５×２００）
	ENDC

t128uS	EQU	0
t25mS	EQU	1
t5S	EQU	5

	ORG	0
	GOTO	INIT	; 初期処理に行く


; ======================== 割込み処理 ========================
	ORG	4		; 割込みベクタ(4番地)を指定する。
	MOVWF	save_w		; W-regセーブ
	SWAPF	STATUS,W
	MOVWF	save_st		; STATUSレジスタセーブ

	BTFSC	INTCON,T0IF	; ＴＭＲ０割込み？
	GOTO	T0INT		;  Yes
	BTFSC	INTCON,INTF	; ＧＰ２／ＩＮＴ割込み？
	GOTO	GP2INT		;  Yes
	GOTO	INTEXIT		;  No


T0INT       ; ＜＜ ＴＭＲ０割込み処理 ＞＞
	BCF	INTCON,T0IF	; 割込みフラグクリア

	BSF	timer,t128uS	; 128μ秒経過フラグをＯＮ

	DECFSZ	C25mS,F		; 25mS経過？
	GOTO	INTEXIT		;  No
	BSF	timer,t25mS
	MOVLW	d'195'
	MOVWF	C25mS		; 25mSカウンタ（128uS×１９５）

	DECFSZ	C5S,F		; 5S経過？
	GOTO	INTEXIT		;  No
	BSF	timer,t5S	; ５秒経過フラグをＯＮ
	MOVLW	d'200'
	MOVWF	C5S		; 5Sカウンタ（25mS×２００）
	GOTO	INTEXIT

GP2INT      ; ＜＜ ＧＰ２／ＩＮＴ割込み処理 ＞＞
	BCF	INTCON,INTF ; 割込みフラグクリア
	MOVLW	d'1'
	MOVWF	napion		; １→ＮａＰｉＯｎ状態

INTEXIT
	SWAPF	save_st,W
	MOVWF	STATUS		; STATUSレジスタロード
	SWAPF	save_w,F
	SWAPF	save_w,W	; W-regロード
	RETFIE			; 割込み許可にしてリターン
    ; ここまで割込み処理


; ================= PICの初期化 =========================
INIT
	MOVLW	07h
	MOVWF	CMCON0		;GP2-0はデジタルＩＯ  

	BSF	STATUS,RP0	;■バンク１に切替え
	MOVLW	0Dh
	MOVWF	TRISIO		; GP0,2,3は入力，GP1,4,5は出力
	MOVLW	088h		; OPTIONレジスタの設定
	MOVWF	OPTION_REG	; ^RBPU:1 ,INTEDG:0 ,T0CS:0 ,PSA:1 ,PS2-PS0:000
	MOVLW	070h		; CLOCK=8MHz
	MOVWF	OSCCON
	CLRF	ANSEL		;デジタルＩＯ（ＡＮ機能を使用しない）
	BCF	STATUS,RP0	;■バンク０に切替え


	CLRF	GPIO		; GPIOをクリア
	CLRF	TMR0		; TMR0をクリア
	MOVLW	0A0h		; INTCONの設定
	MOVWF	INTCON		; GIE:1 ,T0IE:1(TMR0割り込み許可)

	MOVLW	d'195'
	MOVWF	C25mS		; 25mSカウンタ（128uS×１９５）
	MOVLW	d'200'
	MOVWF	C5S		; 5Sカウンタ（25mS×２００）

	CLRF    timer
	CLRF    napion


	; 電源ＯＮ後、ＮａＰｉＯｎの回路が安定するまで５秒待つ
	BSF	GPIO,5		; 電源ＯＮ後ＮａＰｉＯｎが安定するまで高輝度ＬＥＤ一つを点灯
WAIT5S
	BTFSS	timer,t5S	; 5秒経過フラグＯＮ？
	GOTO	WAIT5S		;  No
	BCF	GPIO,5		; 高輝度ＬＥＤ消灯

	BSF	INTCON,INTE	; ＲＢ０／ＩＮＴ割込み許可


; ================= メイン処理 =========================
MAIN
	BTFSS	napion,0	; NaPiOn状態は１？
	GOTO	NAPI2		;  No

NAPI1
    ; ＜＜　NaPiOn状態が１の時（GP2/INT割込み発生）　＞＞
	CLRF	TMR0		; TMR0クリア

	BCF	timer,t5S	; ５秒経過フラグクリア
	MOVLW	d'200'
	MOVWF	C5S		; 5Sカウンタ（25mS×２００）

	MOVLW	d'2'
	MOVWF	napion		; NaPiOn状態を２にする

	GOTO	MAIN

    ; ＜＜　NaPiOn状態が１で無い時　＞＞
NAPI2
	BTFSS	GPIO,3		; 暗い？
	GOTO	SLEEPMODE	;  No

	BTFSS	napion,1	; NaPiOn状態は２？
	GOTO	MAIN		;  No

	BSF	GPIO,1		; GP1をＯＮにする
	BSF	GPIO,4		; GP4をＯＮにする
	BSF	GPIO,5		; GP5をＯＮにする

	BTFSS	timer,t5S	; 5秒経過フラグ=１？
	GOTO	MAIN		;  No

SLEEPMODE
	BCF	GPIO,1		; GP1をＯＦＦにする
	BCF	GPIO,4		; GP4をＯＦＦにする
	BCF	GPIO,5		; GP5をＯＦＦにする
	CLRF	napion		; NaPiOn状態を０にする

	SLEEP			; 省電力モードで待機（GP2/INT割込み待ち）

	MOVLW	d'1'
	MOVWF	napion		; NaPiOn状態を１にする

	GOTO	MAIN


	END
; =========================== ここまで ===============================

---